"rankine calent interm"
"Datos de puntos del ciclo"
P[1] = 100[bar]
$ifnot parametric table
T[1] = 400[C]
$endif
P[2] = 40[bar]
T[3] = 400[C]
P[3] = P[2]
P[4] = 0,07[bar]
P[5] = P[4]
"Datos balance de segunda ley"
Tc = T[1]+100+273,15 [K] "para la parte 4 del problema hay que ponerla en función de T[1]"
Tf = 293,15[K]
"Otros datos"
eta_isen = 0,8 "rendimiento isentrópico de ambas turbinas"
"
--------------------- Resolución ---------------------
"
"Punto 1 - Entrada de turbina"
h[1] = enthalpy(Water;T=T[1];P=P[1])
s[1] = entropy(Water;T=T[1];P=P[1])
"Punto 2 - Salida turbina de alta"
s2s = s[1] "s2s sería la entropía de salida de una turbina ideal"
h2s = enthalpy(Water;P=P[2];s=s2s)
eta_isen = ( h[1] - h[2] )/( h[1] - h2s )
T[2] = temperature(Water;P=P[2];h=h[2])
s[2] = entropy(Water;P=P[2];h=h[2])
"Punto 3 - Entrada turbina de baja"
s[3] = entropy(Water; P=P[3]; T=T[3] )
h[3] = enthalpy(Water; P=P[3]; T=T[3] )
"Punto 4 - salida de turbina de baja"
s4s = s[3] "s24s sería la entropía de salida de una turbina ideal"
h4s = enthalpy(Water;P=P[4];s=s4s)
eta_isen = ( h[3] - h[4] )/( h[3] - h4s )
T[4] = temperature(Water;P=P[4];h=h[4])
s[4] = entropy(Water;P=P[4];h=h[4])
x4 = quality(Water;P=P[4];h=h[4])
"Punto 5 - salida de condensador y entrada de bomba"
h[5]=enthalpy(Water;P=P[5];x=0)
s[5]=entropy(Water;P=P[5];x=0)
T[5]=temperature(Water;P=P[5];h=h[5])
"Punto 6 - salida de bomba . el ejercicio está diseñado para que el trabajo de la bomba sea
despreciable. el punto 5 y 6 son prácticamente los mismos"
s[6] =s[5]"Se asume bomba isentrópica"
P[6] =P[1]
T[6]=temperature(Water;P=P[6];h=h[6])
h[6]=enthalpy(Water;P=P[6];s=s[6])
"Rendimiento 1a ley"
Wtm = (h[1]-h[2]) + (h[3]-h[4]) "las dos turbinas"
Q_cald = (h[1]-h[6]) + (h[3]-h[2]) "calentamiento y recalentamiento"
Q_cond = h[4]-h[5]
eta_I = Wtm/Q_cald
"Rendimiento 2ª ley"
eta_carnot = 1-Tf/Tc
eta_II = eta_I/eta_carnot
"Balances de entropía e irreversibilidad generada"
sigma_turb = s[2]-s[1] + s[4]-s[3]
I_turb_m = sigma_turb*Tf
sigma_bomba = s[6]-s[5]
sigma_cald = s[1]-s[6] - Q_cald/Tc
I_cald_m = sigma_cald*Tf
sigma_cond = s[4]-s[5] + Q_cond/Tc
I_cond_m = sigma_cond*Tf
"Representación gráfica"
T_v[1..9]=[T[1];T[2];T[3];T[4];T[5];T[6];T_evap;T_evap;T[1]]
s_v[1..9]=[s[1];s[2];s[3];s[4];s[5];s[6];s_liq;s_vap;s[1]]
s_vap=entropy(Water;x=1;P=P[1])
s_liq=entropy(Water;x=0;P=P[1])
T_evap=t_sat(Water;P=P[1])
"3paredes, cond con gen"
"Datos Capa A"
T_int = 23[C]
h_int = 7[W/m2-C]
L_A = 0,05[m]
K_A = 0,038[W/m-C]
"Datos Capa B"
L_B = 0,008[m]
"Datos Capa C"
L_C = L_A
K_C = K_A
G = 1000[W/m3]
T_ext = 12[C]
"Tenemos 6 incógnitas A1,A2, B1,B2, C1,C2"
"BC - 1 - Borde interior/izquierdo de la capa A"
-K_A*A_1=h_int*(T_int-A_2)
"BC - 2 - Unión entre capa A y B. Continuidad de temperatura"
A_1*L_A+A_2 = B_2
"BC - 3 - Unión entre capa A y B. Continuidad de flujo"
-K_A*A_1 = -K_B*B_1
"BC - 4 - Unión entre capa B y C. Continuidad de temperatura"
B_1*L_B+B_2 = C_2
"BC - 5 - Unión entre capa B y C. Continuidad de flujo"
-K_B*B_1=-K_C*C_1
"BC - 6 - Borde exterior/derecho , temperatura exterior impuesta"
-G/K_C*L_C^2/2 + C_1*L_C + C_2 = T_ext
"Cerramos el problema definiendo la conductividad de B/Aluminio"
T_Bmed = (B_2+C_2)/2
K_B=Conductivity(Aluminum; T=T_Bmed)
"K_B=Conductivity(Sand; T=T_Bmed)"
"Definimos temperaturas para representarlas"
TA_left = A_2
TA_right = A_1*L_A + A_2
TB_left = B_2
TB_right = B_1*L_B + B_2
TC_left = C_2
TC_right = -G/K_C*L_C^2/2 + C_1*L_C + C_2
"Para Representar la capa C"
$IFnot ParametricTable
vxc=0"vector auxiliar para rep. gráfica de posición en la capa C"
$endif
vTC = -G/K_C*vxc^2/2 + C_1*vxc + C_2"vector auxiliar para rep. gráfica de la temp en la capa C"
"aletas procesador"
Pot=20[W]
L_p=5 [cm]*convert(cm;m)
e_p=4 [mm]*convert(mm;m)
N_a=34
T_amb=20 [C]
h= 7 [W/m^2-C]
k_Si=122 [W/m-C]
k_Al=237 [W/m-C]
delta=0,2 [mm]*convert(mm;m)
T_max_Si=50 [C]
"Calculos Aletas"
P=2*L_p+2*delta "Perímetro de la sección conductiva de la aleta"
A=L_p*delta "Area de la sección conductiva de la aleta"
m=sqrt((h*P)/(k_Al*A)) "Calculo de m"
eta=tanh(m*L_c)/(m*L_c) "Calculos de la efectividad de la aleta"
L_c=L+delta/2 "Longitud corregida de la aleta"
Pot=h*(A_l+A_a*eta)*(T_Al-T_amb) "La potencia se disipa a traves de las aletas y del area libre"
Pot=k_Al*L_p^2/delta*(T_Si-T_Al) "La potencia atraviesa la plancha de aluminio"
T_Si_0=T_Si+Pot*e_p/(L_p^2*2*k_Si) "Expresión que relaciona la temperatura máxima del procesador (cara aislada) con la de la otra cara cuando hay generación de valor Pot/L_p^2"
T_Si_0=T_max_Si "Inicialmente se fija la temperatura anterior a la máxima admisible (despues se oculta para que la calcule cuando se redondea el número de aletas)"
A_l=L_p*(L_p-N_a*delta) "Area libre de aletas"
A_a=N_a*(2*L+delta)*L_p "Area de aletas"